[DevOps] Jacoco

Jacoco!

Jacoco는 Java 플랫폼에서 코드 커버리지(Code Coverage)를 측정하기 위한 도구로 코드 커버리지 측정 결과를 HTML,XML,CSV등의 형식으로 제공해줍니다.결과에 따른 최소 기준치를 정하여 충족하지 못하면 경고를 하거나 코드의 품질관리를 돕습니다.

Code Coverage?

소프트웨어에서 테스트코드가 얼마나 코드들을 테스트하고 있는지 알려주는 지표

사용법 및 사용모습

1. build.gradle.kts에 스크립트 추가

tasks.withType<Test> {
    useJUnitPlatform()
    finalizedBy(tasks.jacocoTestReport) // 테스트 실행 후 자동으로 리포트 생성
}

jacoco {
    toolVersion = "0.8.8"
}

tasks.jacocoTestReport {
    dependsOn(tasks.test)
    
    reports {
        xml.required.set(true)
        html.required.set(true)
        csv.required.set(false)
    }
    
    // 리포트에서 제외할 클래스 패턴 설정
    classDirectories.setFrom(
        files(classDirectories.files.map {
            fileTree(it) {
                exclude(
                    "**/*Application*",
                    "**/*Config*",
                    "**/*Dto*",
                    "**/*Entity*",
                    "**/generated/**"
                )
            }
        })
    )
}

tasks.jacocoTestCoverageVerification {
    dependsOn(tasks.jacocoTestReport)
    
    violationRules {
        rule {
            limit {
                minimum = "0.80".toBigDecimal() // 최소 80% 커버리지
            }
        }
        
        rule {
            enabled = true
            element = "CLASS"
            
            limit {
                counter = "BRANCH"
                value = "COVEREDRATIO"
                minimum = "0.70".toBigDecimal()
            }
            
            limit {
                counter = "LINE"
                value = "COVEREDRATIO"
                minimum = "0.80".toBigDecimal()
            }
            
            excludes = listOf(
                "*.test.*",
                "*.Kotlin*",
                "*Application*",
                "*Config*"
            )
        }
    }
}

tasks.check {
    dependsOn(tasks.jacocoTestCoverageVerification)
}

2. Jacoco 실행

# 테스트 실행 및 커버리지 검증 및 리포트 생성
./gradlew test jacocoTestReport jacocoTestCoverageVerification

# 전체 빌드 (커버리지 검증 포함)
./gradlew build

3. 리포트 확인

• build/reports/jacoco/test/html/index.html
• build/reports/jacoco/test/jacocoTestReport.xml

브라우저 등의 도구를 이용하여 커버리지 리포트를 확인할 수 있다